Definieren Sie ein Terraform-Projekt Bereitstellen des Clusters Erforderliche Berechtigungen

Einen Cluster mit Terraform erstellen

Bei der Nutzung AWS ParallelCluster zahlen Sie nur für die AWS Ressourcen, die beim Erstellen oder Aktualisieren von AWS ParallelCluster Images und Clustern erstellt werden. Weitere Informationen finden Sie unter AWS Dienste verwendet von AWS ParallelCluster.

Voraussetzungen

Terraform v1.5.7+ ist installiert.
AWS ParallelCluster APIv3.8.0+ ist in Ihrem Konto bereitgestellt. Siehe ParallelCluster API mit Terraform bereitstellen.
IAM-Rolle mit den Berechtigungen zum Aufrufen der API. ParallelCluster Siehe [Erforderliche Berechtigungen]

Definieren Sie ein Terraform-Projekt

In diesem Tutorial definieren Sie ein einfaches Terraform-Projekt zur Bereitstellung eines Clusters.

Erstellen Sie ein Verzeichnis namens. my-clusters

Alle Dateien, die Sie erstellen, befinden sich in diesem Verzeichnis.

Erstellen Sie die Dateiterraform.tf, um den ParallelCluster Anbieter zu importieren.


terraform {
  required_version = ">= 1.5.7"
  required_providers {
    aws-parallelcluster = {
      source  = "aws-tf/aws-parallelcluster"
      version = "1.0.0"
    }
  }
}

Erstellen Sie die Dateiproviders.tf, um die AWS Anbieter ParallelCluster und zu konfigurieren.


provider "aws" {
  region  = var.region
  profile = var.profile
}

provider "aws-parallelcluster" {
  region         = var.region
  profile        = var.profile
  api_stack_name = var.api_stack_name
  use_user_role  = true
}

Erstellen Sie die Dateimain.tf, um die Ressourcen mithilfe des ParallelCluster Moduls zu definieren.


module "pcluster" {
  source  = "aws-tf/parallelcluster/aws"
  version = "1.0.0"

  region                = var.region
  api_stack_name        = var.api_stack_name
  api_version           = var.api_version
  deploy_pcluster_api   = false

  template_vars         = local.config_vars
  cluster_configs       = local.cluster_configs
  config_path           = "config/clusters.yaml"
}

Erstellen Sie die Dateiclusters.tf, um mehrere Cluster als lokale Terraform-Variablen zu definieren.

Anmerkung

Sie können mehrere Cluster innerhalb des cluster_config Elements definieren. Für jeden Cluster können Sie die Cluster-Eigenschaften innerhalb der lokalen Variablen explizit definieren (sieheDemoCluster01) oder auf eine externe Datei verweisen (sieheDemoCluster02).

Informationen zu den Clustereigenschaften, die Sie innerhalb des Konfigurationselements festlegen können, finden Sie unterCluster-Konfigurationsdatei.

Informationen zu den Optionen, die Sie für die Clustererstellung festlegen können, finden Sie unterpcluster create-cluster.


locals {
  cluster_configs = {
    DemoCluster01 : {
      region : local.config_vars.region
      rollbackOnFailure : false
      validationFailureLevel : "WARNING"
      suppressValidators : [
        "type:KeyPairValidator"
      ]
      configuration : {
        Region : local.config_vars.region
        Image : {
          Os : "alinux2"
        }
        HeadNode : {
          InstanceType : "t3.small"
          Networking : {
            SubnetId : local.config_vars.subnet
          }
          Iam : {
            AdditionalIamPolicies : [
              { Policy : "arn:aws:iam::aws:policy/AmazonSSMManagedInstanceCore" }
            ]
          }
        }
        Scheduling : {
          Scheduler : "slurm"
          SlurmQueues : [{
            Name : "queue1"
            CapacityType : "ONDEMAND"
            Networking : {
              SubnetIds : [local.config_vars.subnet]
            }
            Iam : {
              AdditionalIamPolicies : [
                { Policy : "arn:aws:iam::aws:policy/AmazonSSMManagedInstanceCore" }
              ]
            }
            ComputeResources : [{
              Name : "compute"
              InstanceType : "t3.small"
              MinCount : "1"
              MaxCount : "4"
            }]
          }]
          SlurmSettings : {
            QueueUpdateStrategy : "TERMINATE"
          }
        }
      }
    }
    DemoCluster02 : {
      configuration : "config/cluster_config.yaml"
    }
  }
}

Erstellen Sie die Dateiconfig/clusters.yaml, um mehrere Cluster als YAML-Konfiguration zu definieren.


DemoCluster03:
  region: ${region}
  rollbackOnFailure: true
  validationFailureLevel: WARNING
  suppressValidators:
    - type:KeyPairValidator
  configuration: config/cluster_config.yaml
DemoCluster04:
  region: ${region}
  rollbackOnFailure: false
  configuration: config/cluster_config.yaml

Erstellen Sie die Dateiconfig/cluster_config.yaml, bei der es sich um eine ParallelCluster Standardkonfigurationsdatei handelt, in die Terraform-Variablen eingefügt werden können.

Informationen zu den Cluster-Eigenschaften, die Sie innerhalb des Konfigurationselements festlegen können, finden Sie unter. Cluster-Konfigurationsdatei


Region: ${region}
Image:
 Os: alinux2
HeadNode:
 InstanceType: t3.small
 Networking:
   SubnetId: ${subnet}
 Iam:
   AdditionalIamPolicies:
     - Policy: arn:aws:iam::aws:policy/AmazonSSMManagedInstanceCore
Scheduling:
 Scheduler: slurm
 SlurmQueues:
   - Name: queue1
     CapacityType: ONDEMAND
     Networking:
       SubnetIds:
         - ${subnet}
     Iam:
       AdditionalIamPolicies:
         - Policy: arn:aws:iam::aws:policy/AmazonSSMManagedInstanceCore
     ComputeResources:
       - Name: compute
         InstanceType: t3.small
         MinCount: 1
         MaxCount: 5
 SlurmSettings:
   QueueUpdateStrategy: TERMINATE

Erstellen Sie die Dateiclusters_vars.tf, um die Variablen zu definieren, die in Clusterkonfigurationen eingefügt werden können.

Mit dieser Datei können Sie dynamische Werte definieren, die in Clusterkonfigurationen verwendet werden können, z. B. Region und Subnetz.

In diesem Beispiel werden Werte direkt aus den Projektvariablen abgerufen. Möglicherweise müssen Sie jedoch benutzerdefinierte Logik verwenden, um sie zu ermitteln.
```
locals {
  config_vars = {
    subnet = var.subnet_id
    region = var.cluster_region
  }
}
```

Erstellen Sie die Dateivariables.tf, um die Variablen zu definieren, die für dieses Projekt eingefügt werden können.


variable "region" {
  description = "The region the ParallelCluster API is deployed in."
  type        = string
  default     = "us-east-1"
}

variable "cluster_region" {
  description = "The region the clusters will be deployed in."
  type        = string
  default     = "us-east-1"
}

variable "profile" {
  type        = string
  description = "The AWS profile used to deploy the clusters."
  default     = null
}

variable "subnet_id" {
  type        = string
  description = "The id of the subnet to be used for the ParallelCluster instances."
}

variable "api_stack_name" {
  type        = string
  description = "The name of the CloudFormation stack used to deploy the ParallelCluster API."
  default     = "ParallelCluster"
}

variable "api_version" {
  type        = string
  description = "The version of the ParallelCluster API."
}

Erstellen Sie die Dateiterraform.tfvars, um beliebige Werte für die Variablen festzulegen.

In der folgenden Datei werden die Cluster eu-west-1 innerhalb des subnet-123456789 Subnetzes mithilfe der vorhandenen ParallelCluster API 3.10.0 bereitgestellt, die bereits us-east-1 mit dem Stacknamen bereitgestellt wurde. MyParallelClusterAPI-310
```
region = "us-east-1"
api_stack_name = "MyParallelClusterAPI-310"
api_version = "3.10.0"

cluster_region = "eu-west-1"
subnet_id = "subnet-123456789"
```

Erstellen Sie die Dateioutputs.tf, um die von diesem Projekt zurückgegebenen Ausgaben zu definieren.


output "clusters" {
  value = module.pcluster.clusters
}

Das Projektverzeichnis ist:


my-clusters
├── config
│   ├── cluster_config.yaml - Cluster configuration, where terraform variables can be injected..
│   └── clusters.yaml - File listing all the clusters to deploy.
├── clusters.tf - Clusters defined as Terraform local variables.
├── clusters_vars.tf - Variables that can be injected into cluster configurations.
├── main.tf - Terraform entrypoint where the ParallelCluster module is configured.
├── outputs.tf - Defines the cluster as a Terraform output.
├── providers.tf - Configures the providers: ParallelCluster and AWS.
├── terraform.tf - Import the ParallelCluster provider.
├── terraform.tfvars - Defines values for variables, e.g. region, PCAPI stack name.
└── variables.tf - Defines the variables, e.g. region, PCAPI stack name.

Bereitstellen des Clusters

Um den Cluster bereitzustellen, führen Sie die Terraform-Standardbefehle der Reihe nach aus.

Anmerkung

In diesem Beispiel wird davon ausgegangen, dass Sie die ParallelCluster API bereits in Ihrem Konto bereitgestellt haben.

Erstellen Sie das Projekt:
```
terraform init
```
Definieren Sie den Bereitstellungsplan:
```
terraform plan -out tfplan
```
Stellen Sie den Plan bereit:
```
terraform apply tfplan
```

Stellen Sie die ParallelCluster API mit Clustern bereit

Wenn Sie die ParallelCluster API nicht bereitgestellt haben und sie mit den Clustern bereitstellen möchten, ändern Sie die folgenden Dateien:

main.tf


module "pcluster" {
  source  = "aws-tf/aws/parallelcluster"
  version = "1.0.0"

  region                = var.region
  api_stack_name        = var.api_stack_name
  api_version           = var.api_version
  deploy_pcluster_api   = true

  template_vars         = local.config_vars
  cluster_configs       = local.cluster_configs
  config_path           = "config/clusters.yaml"
}

providers.tf


provider "aws-parallelcluster" {
  region   = var.region
  profile  = var.profile
  endpoint = module.pcluster.pcluster_api_stack_outputs.ParallelClusterApiInvokeUrl
  role_arn = module.pcluster.pcluster_api_stack_outputs.ParallelClusterApiUserRole
}

Erforderliche Berechtigungen

Sie benötigen die folgenden Berechtigungen, um einen Cluster mit Terraform bereitzustellen:

übernehme die ParallelCluster API-Rolle, die für die Interaktion mit der API zuständig ist ParallelCluster
Beschreiben Sie den AWS CloudFormation ParallelCluster API-Stack, um zu überprüfen, ob er existiert, und rufen Sie seine Parameter und Ausgaben ab


{
    "Version": "2012-10-17",
    "Statement": [
        {
            "Action": "sts:AssumeRole",
            "Resource": "arn:PARTITION:iam::ACCOUNT:role/PCAPIUserRole-*",
            "Effect": "Allow",
            "Sid": "AssumePCAPIUserRole"
        },
        {
            "Action": [
                "cloudformation:DescribeStacks"
            ],
            "Resource": "arn:PARTITION:cloudformation:REGION:ACCOUNT:stack/*",
            "Effect": "Allow",
            "Sid": "CloudFormation"
        }
    ]
}

Warnung JavaScript ist in Ihrem Browser nicht verfügbar oder deaktiviert.

Zur Nutzung der AWS-Dokumentation muss JavaScript aktiviert sein. Weitere Informationen finden auf den Hilfe-Seiten Ihres Browsers.

Dokumentkonventionen

ParallelCluster API mit Terraform bereitstellen

Erstellen eines benutzerdefinierten AMI mit Terraform