设置 Gradle 项目

您可以使用 Gradle 来设置和构建AWS SDK for Java项目。

要管理 Gradle 项目的开发工具包依赖项，请将AWS SDK for Java的 Maven 材料清单 (BOM) 导入到 build.gradle 文件中。

注意

在以下示例中，将 Gradle 编译文件中的 2.20.56 替换为最新版本的AWS SDK for Java v2。在 AWS SDK for JavaAPI 参考版本 2.x 中查找最新版本。

1. 将 BOM（物料清单）添加到文件的 “依赖关系” 部分。

   ...
   dependencies {
       implementation platform('software.amazon.awssdk:bom:2.20.56')
   
   
    // Declare individual SDK dependencies without version.
    ...
   }

2. 在 dependencies 部分中指定要使用的开发工具包模块。例如，以下内容包括亚马逊简单存储服务的依赖关系。

   ...
   dependencies {
    ...
    implementation 'software.amazon.awssdk:s3'
    ...
   }

Gradle 会自动使用 BOM 中的信息来解析开发工具包依赖项的正确版本。

以下显示了使用 Groovy 和 Kotlin DSL 的完整 Gradle 编译文件。编译文件包含 Amazon S3、身份验证、日志记录和测试的依赖关系。Java 的源和目标版本是版本 11。

Groovy DSL (build.gradle)

plugins {
    id 'java'
}

group = 'aws.test'
version = '1.0-SNAPSHOT'

sourceCompatibility JavaVersion.VERSION_11
targetCompatibility JavaVersion.VERSION_11

repositories {
    mavenCentral()
}

dependencies {
    implementation platform('software.amazon.awssdk:bom:2.20.56')
    implementation 'software.amazon.awssdk:s3:'
    implementation 'software.amazon.awssdk:sso'
    implementation 'software.amazon.awssdk:ssooidc'
    implementation 'org.slf4j:slf4j-simple:2.0.5'
    testImplementation platform('org.junit:junit-bom:5.9.1')
    testImplementation 'org.junit.jupiter:junit-jupiter'
}

test {
    useJUnitPlatform()
}

Kotlin DSL (build.gradle.kts)

plugins {
    `java-library`
}

group = "aws.test"
version = "1.0-SNAPSHOT"

java {
    sourceCompatibility = JavaVersion.VERSION_11
    targetCompatibility = JavaVersion.VERSION_11
}

repositories {
    mavenCentral()
}

dependencies {
    implementation(platform("software.amazon.awssdk:bom:2.20.56"))
    implementation("software.amazon.awssdk:s3")
    implementation("software.amazon.awssdk:sso")
    implementation("software.amazon.awssdk:ssooidc")
    implementation("org.slf4j:slf4j-simple:2.0.5")
    testImplementation(platform("org.junit:junit-bom:5.9.1"))
    testImplementation("org.junit.jupiter:junit-jupiter")
}

tasks.test {
    useJUnitPlatform()
}

注意

在前面的示例中，将 Amazon S3 的依赖项替换为将在项目中使用的AWS服务的依赖关系。由AWS SDK for Java BOM 管理的模块（依赖关系）在 M aven 中央存储库中列出。

有关使用 BOM 指定 SDK 依赖关系的更多信息，请参阅设置 Apache Maven 项目。