地理空間のトラブルシューティング - Amazon QuickSight
ジオコーディングに関する問題緯度と経度に関する問題

地理空間のトラブルシューティング

このセクションでは、地理空間データを正しく処理するための Amazon QuickSight の要件について説明します。Amazon QuickSight が地理空間データを地理空間として認識しない場合は、このセクションを使用して問題をトラブルシューティングします。データが地理空間ビジュアルで適切に動作するように、リストされたガイドラインに従っていることを確認します。

注記

現在、Amazon QuickSight の地理空間グラフは一部の AWS リージョンでサポートされておらず、これには中国が含まれます。AWS では、より多くのリージョンへのサポートの追加に取り組んでいます。

お客様の地域が、ここに一覧表示されたすべてのガイドラインに従っているにもかかわらずエラーが発生する場合は、Amazon QuickSight コンソール内から Amazon QuickSight チームにお問い合わせください。

ジオコーディングに関する問題

Amazon QuickSight のジオコードは、緯度と経度の座標に名前を配置します。これらの座標を使用して、マップに地名を表示します。ジオコードできない場所は Amazon QuickSight によりスキップされます。

このプロセスを正しく機能させるには、データに少なくとも国が含まれている必要があります。また、親の地名の内部に重複した地名を使用することはできません。

いくつかの問題で地名がマップチャートに表示されないことがあります。これらの問題には、以下に示すように、サポートされていない場所、あいまいな場所、または無効な場所などがあります。

サポートされていない地域に関する問題

サポートされていない場所をマップするには、データに緯度と経度の座標を含めます。これらの座標を地理空間フィールドウェルに使用して、場所をマップチャートに表示します。

あいまいな場所に関する問題

地理空間データには、あいまいな場所を含めることはできません。例えば、データに Springfield という都市名があるが、階層の次のレベルは国だとします。複数の州に Springfield という名前の都市があるので、その場所を地図上の特定の地点にジオコードすることは不可能です。

この問題を回避するため、マップチャート上に表示される場所を特定するのに十分な地理的なデータを追加できます。例えば、データとその階層に州レベルを追加します。または、緯度と経度を追加することもあります。

無効な地理空間データに関する問題

無効な地理空間データは、地名 (都市など) が正しくない親 (州など) の下にリストされている場合に発生します。この問題は、単純なスペルミス、またはデータ入力エラーの可能性があります。

注記

Amazon QuickSight では、地域 (西海岸や南部など) は地理空間データとしてサポートされません。ただし、ビジュアル内でフィルタとして使用することはできます。

ジオコーディングにおけるデフォルト国に関する問題

正しいデフォルトの国を使用していることを確認します。

各階層のデフォルトは、階層の作成時に選択した国または国フィールドに基づいています。

このデフォルトを変更するには、[Create hierarchy (階層の作成)] 画面に戻ります。階層を編集または作成して、別の国を選択します。

階層を作成しない場合、デフォルト国は AWS リージョンに基づきます。詳細については次の表を参照してください。

リージョン デフォルト国

米国西部 (オレゴン) リージョン

米国東部 (オハイオ) リージョン

米国東部 (バージニア北部) リージョン

 米国
アジアパシフィック (シンガポール) シンガポール
アジアパシフィック (シドニー) オーストラリア
欧州 (アイルランド) リージョン アイルランド

緯度と経度に関する問題

Amazon QuickSight は、バックグラウンドで緯度と経度の座標を使用して、マップ上の地名を見つけます。ただし、座標を使用して地名を使用せずにマップを作成することもできます。この方法はサポートされていない地名でも機能します。

緯度と経度の値は数値である必要があります。例えば、28.5383355 -81.3792365 で示されるマップポイントは、Amazon QuickSight と互換性があります。しかし、28° 32' 18.0096'' N 81° 22' 45.2424'' W にはありません。

緯度と経度の座標の有効範囲

Amazon QuickSight は特定の範囲内の緯度と経度をサポートします。

座標 有効範囲
緯度 -90～90
経度 -180～180

Amazon QuickSight では、これらの範囲外のデータはすべてスキップされます。範囲外の地点は、マップチャートにマッピングできません。

度、分、秒 (DMS) 形式の座標の使用

計算フィールドを計算式と使用して、キャラクタ文字列から数値の緯度と経度を作成できます。このセクションでは、Amazon QuickSight で計算フィールドを作成し、GPS の緯度と経度を数値の緯度と経度に解析するさまざまな方法について説明します。

次のサンプルでは、緯度と経度を異なるフィールドから数値形式に変換します。例えば、スペースを区切り文字として使用して、51° 30' 26.4636'' N 0° 7' 39.9288'' W を解析するとします。この場合、次のサンプルのようなものを使用して、結果のフィールドを数値の緯度と経度に変換することができます。

この例では、秒の後に 2 つの一重引用符が続きます。データに二重引用符がある場合は、strlen(LatSec)-1) の代わりに strlen(LatSec)-2) を使用できます。

/*Latitude*/
        ifelse(
        LatDir = "N",
        parseInt(split(LatDeg, "°", 1)) +
            (parseDecimal(split(LatMin, "'", 1) ) /60) +
            (parseDecimal((substring(LatSec, 1, strlen(LatSec)-2) ) ) /3600),
        (parseInt(split(LatDeg, "°", 1)) +
            (parseDecimal(split(LatMin, "'", 1) ) /60) +
            (parseDecimal((substring(LatSec, 1, strlen(LatSec)-2) ) ) /3600)) * -1
        )

/*Longitude*/
        ifelse(
        LongDir = "E",
        parseInt(split(LongDeg, "°", 1)) +
            (parseDecimal(split(LongMin, "'", 1) ) /60) +
            (parseDecimal((substring(LongSec, 1, strlen(LongSec)-2) ) ) /3600),
        (parseInt(split(LongDeg, "°", 1)) +
            (parseDecimal(split(LongMin, "'", 1) ) /60) +
            (parseDecimal((substring(LongSec, 1, strlen(LongSec)-2) ) ) /3600)) * -1
        )

度、分また秒の記号がデータに含まれていない場合は、式は次のようになります。

/*Latitude*/
    ifelse(
        LatDir = "N",
        (LatDeg + (LatMin / 60) + (LatSec / 3600)),
        (LatDeg + (LatMin / 60) + (LatSec / 3600)) * -1
    )

/*Longitude*/
    ifelse(
        LongDir = "E",
        (LongDeg + (LongMin / 60) + (LongSec / 3600)),
        (LongDeg + (LongMin / 60) + (LongSec / 3600)) * -1
    )

次のサンプルでは、53°21'N 06°15'W を数値形式に変換します。ただし、秒がないので、この場所は正確にはマッピングされません。

/*Latitude*/
ifelse(
    right(Latitude, 1) = "N",
    (parseInt(split(Latitude, '°', 1)) +
        parseDecimal(substring(Latitude, (locate(Latitude, '°',3)+1),  2) ) / 60) ,
    (parseInt(split(Latitude, '°', 1)) +
        parseDecimal(substring(Latitude, (locate(Latitude, '°',3)+1),  2) ) / 60) * -1
)

/*Longitude*/
ifelse(
    right(Longitude, 1) = "E",
    (parseInt(split(Longitude, '°', 1)) +
        parseDecimal(substring(Longitude, (locate(Longitude, '°',3)+1),  2) ) / 60) ,
    (parseInt(split(Longitude, '°', 1)) +
        parseDecimal(substring(Longitude, (locate(Longitude, '°',3)+1),  2) ) / 60) * -1
)

GPS の緯度と経度の形式にはばらつきがあるため、データに一致するように式をカスタマイズします。詳細については、以下を参照してください。